class Words {
 
  Hashtable ht=new Hashtable();
  PFont font,smallfont;
  PImage img,masker;
  int maxcount=1;
  String mostpopular="";
  String newest="";
  float c=0;
  float radius=0;
  float f=1;
  float x,y;
  float a=width/2;
  
  float minAlpha=50,maxAlpha=175;
  float minTextAlpha=5,maxTextAlpha=200;
  float minColor=50,maxColor=255;
  float minRadius=3,maxRadius=40;
  float minFont=1,maxFont=38;
  float cstep = .01;

  float offsetY=maxFont;
  float offsetX=width/2;

  Words() {
    font = loadFont("Garamond-38.vlw");
    smallfont = loadFont("Garamond-18.vlw");
  }
  void reset() {
    ht.clear(); 
    maxcount = 0;
    mostpopular = "";
  }
  void addWord(String txt) {
    Word word;
    if (ht.containsKey(txt)) {
      word = (Word)ht.get(txt);
      word.count++;
    } else {
      word = new Word(txt);
      newest = txt;
    }
    if (word.count>maxcount) {
      maxcount=word.count;
      mostpopular=txt;
    }
    ht.put(txt,word);
  }
  
  void printWords() {
    for (Enumeration e = ht.keys() ; e.hasMoreElements() ;) {
      String name = e.nextElement().toString();
      Word word = (Word)ht.get(name);
      println(word.txt + ": " + word.count);
    }   
  }
  
  Word[] getWords() {
    Collection c = ht.values();
    return (Word[]) c.toArray(new Word[0]); 
  }
  
  void draw() {
    Word words[] = getWords();
    
    if (mousePressed) {
      cstep=.1*float(mouseY)/float(height);
      f=166*float(mouseX)/float(width);
    }
        
    if ((c+=cstep)>TWO_PI) c=0;
               
    float g = mouseY;
    float h = mouseX;
    line(0,g,width,g);
    line(h,0,h,height);
 
    for (int i=0; i<words.length; i++) {
        float m=float(i)/words.length;
        float mr=float(words[i].count)/maxcount;

        if (pmouseX!=mouseX) a=mouseX/2;
        
        x=sin(f*TWO_PI*m+c)*a + offsetX;  //*abs(float(width/2)-mouseX)
        y=m*height;
      
        words[i].moveTo(x,y);
        
        stroke(fColor,abc(mr,minAlpha,maxAlpha));
        fill(fColor,abc(mr,minAlpha,maxAlpha));

        radius = abc(mr,minRadius,maxRadius);
        ellipse(words[i].x,words[i].y,radius,radius);
        
        fill(fColor,abc(mr,minTextAlpha,maxTextAlpha));
        textFont(font, abc(mr,minFont,maxFont));
        text(words[i].txt,words[i].x+20,words[i].y);       
    }

    fill(bgColor,180);
    rect(0,0,160,height);
    fill(fColor);
    textAlign(LEFT);
    textFont(smallfont, 18); text("Unique words: ",10,30);
    textFont(font, 38); text(words.length,10,70);
    textFont(smallfont, 18); text("Most popular: ",10,100);
    textFont(font, 38); text(mostpopular,10,140);
    textFont(smallfont, 18); text("Newest word: ",10,170);
    textFont(font, 38); text(newest,10,210);
    textFont(smallfont, 18); text("Occurances: ",10,240);
    textFont(font, 38); text(maxcount,10,280);
    textFont(smallfont, 18); text("Frequency (?/?): ",10,310);
    textFont(font, 38); text(int(f),10,350);
    textFont(smallfont, 18); text("Speed (?/?): ",10,380);
    textFont(font, 38); text(int(cstep*1000),10,420);
    line(10,430,150,430);
    textFont(smallfont, 18); text("Reset with spacebar",10,450);
    textFont(smallfont, 18); text("Rick Companje",10,height-30);
    textFont(smallfont, 18); text("2006-06-27",10,height-10);
  }
}

float abc(float factor,float minimum,float maximum) {
  return factor*(maximum-minimum)+minimum;
}